一個啟動同一個子項目的多個分割區的監督程式。

某些程序可能會成為大型系統中的瓶頸。如果這些程序可以輕易地分割其狀態，且其間沒有依賴關係，則可以使用 PartitionSupervisor 來建立多個獨立且分離的分割區。

一旦 PartitionSupervisor 啟動，就可以使用 {:via, PartitionSupervisor, {name, key}} 傳送給其子項，其中 name 是 PartitionSupervisor 的名稱，而 key 則用於路由。

此模組於 Elixir v1.14.0 中引入。

簡單範例

讓我們從一個本身沒有用的範例開始，但它顯示了分割區是如何啟動以及訊息是如何路由到它們的。

以下是一個玩具 GenServer，它只是收集給它的訊息。它會列印它們以方便說明。

defmodule Collector do
  use GenServer

  def start_link(args) do
    GenServer.start_link(__MODULE__, args)
  end

  def init(args) do
    IO.inspect([__MODULE__, " got args ", args, " in ", self()])
    {:ok, _initial_state = []}
  end

  def collect(server, msg) do
    GenServer.call(server, {:collect, msg})
  end

  def handle_call({:collect, msg}, _from, state) do
    new_state = [msg | state]
    IO.inspect(["current messages:", new_state, " in process", self()])
    {:reply, :ok, new_state}
  end
end

要執行多個這樣的伺服器，我們可以將它們放在 PartitionSupervisor 下，方法是在我們的監督樹中放置這個

{PartitionSupervisor,
  child_spec: Collector.child_spec([some: :arg]),
  name: MyApp.PartitionSupervisor
}

我們可以使用「via tuple」傳送訊息給它們

# The key is used to route our message to a particular instance.
key = 1
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :hi)
# ["current messages:", [:hi], " in process", #PID<0.602.0>]
:ok
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :ho)
# ["current messages:", [:ho, :hi], " in process", #PID<0.602.0>]
:ok

# With a different key, the message will be routed to a different instance.
key = 2
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :a)
# ["current messages:", [:a], " in process", #PID<0.603.0>]
:ok
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :b)
# ["current messages:", [:b, :a], " in process", #PID<0.603.0>]
:ok

現在讓我們繼續一個有用的範例。

DynamicSupervisor 範例

DynamicSupervisor 是負責啟動其他程序的單一程序。在某些應用程式中，DynamicSupervisor 可能會成為瓶頸。為了解決這個問題，你可以透過 PartitionSupervisor 啟動多個 DynamicSupervisor 執行個體，然後選擇一個「隨機」執行個體在上面啟動子項。

不要啟動單一的 DynamicSupervisor

children = [
  {DynamicSupervisor, name: MyApp.DynamicSupervisor}
]

Supervisor.start_link(children, strategy: :one_for_one)

並直接在那個動態監督程式上啟動子項

DynamicSupervisor.start_child(MyApp.DynamicSupervisor, {Agent, fn -> %{} end})

你可以將動態監督程式啟動在 PartitionSupervisor 下

children = [
  {PartitionSupervisor,
   child_spec: DynamicSupervisor,
   name: MyApp.DynamicSupervisors}
]

Supervisor.start_link(children, strategy: :one_for_one)

然後

DynamicSupervisor.start_child(
  {:via, PartitionSupervisor, {MyApp.DynamicSupervisors, self()}},
  {Agent, fn -> %{} end}
)

在上面的程式碼中，我們啟動一個分割監督器，它會預設為您的機器中的每個核心啟動一個動態監督器。然後，您不是透過名稱來呼叫 DynamicSupervisor，而是透過分割監督器使用 {:via, PartitionSupervisor, {name, key}} 格式來呼叫它。我們選擇 self() 作為路由金鑰，這表示每個程序將被指定現有的動態監督器之一。請參閱 start_link/1 以查看 PartitionSupervisor 支援的所有選項。

實作注意事項

PartitionSupervisor 使用 ETS 表格或 Registry 來管理所有分割。在底層，PartitionSupervisor 為每個分割產生一個子規格，然後充當常規監督器。每個子規格的 ID 是分割號碼。

對於路由，我們使用兩種策略。如果 key 是整數，則使用 rem(abs(key), partitions) 來路由，其中 partitions 是分割數。否則，它使用 :erlang.phash2(key, partitions)。特定的路由可能會在未來改變，因此不能依賴它。如果您想為特定金鑰擷取特定 PID，您可以使用 GenServer.whereis({:via, PartitionSupervisor, {name, key}})。