檢視原始碼 MapSet (Elixir v1.16.2)
用於集合的函式。
集合是一種資料結構，可以包含任何種類的唯一元素，且沒有特定順序。 MapSet 是 Elixir 中「首選」的集合資料結構。
可以使用 MapSet.new/0 建立集合。
iex> MapSet.new()
MapSet.new([])集合中的元素不必是同種類型，而且可以使用 MapSet.new/1 從 列舉 填入元素。
iex> MapSet.new([1, :two, {"three"}])
MapSet.new([1, :two, {"three"}])可以使用 MapSet.put/2 插入元素。
iex> MapSet.new([2]) |> MapSet.put(4) |> MapSet.put(0)
MapSet.new([0, 2, 4])根據定義，集合不能包含重複的元素：在集合中插入已存在的元素時，插入動作只會是空操作。
iex> map_set = MapSet.new()
iex> MapSet.put(map_set, "foo")
MapSet.new(["foo"])
iex> map_set |> MapSet.put("foo") |> MapSet.put("foo")
MapSet.new(["foo"])在內部，MapSet 使用 %MapSet{} 結構表示。每當需要對應到 MapSet 的模式時，都可以使用這個結構。
iex> match?(%MapSet{}, MapSet.new())
true不過，請注意結構欄位是私有的，不能直接存取；請使用這個模組中的函式對集合執行操作。
也可以從其他集合類型資料結構開始建立 MapSet：例如，請參閱 MapSet.new/1 或 Enum.into/2。
MapSet 建構在 Erlang 的 :sets (版本 2) 之上。這表示它們共用許多特性，包括對數時間複雜度。Erlang :sets (版本 2) 建構在映射之上，因此請參閱 Map 的文件，以取得更多關於其執行時間複雜度的資訊。
摘要
函數
從 map_set 中刪除 值。
傳回一個集合，為 map_set1 減去 map_set2 的成員。
檢查 map_set1 和 map_set2 是否沒有共同成員。
檢查兩個集合是否相等。
透過只傳回 map_set 中呼叫 fun 會傳回真值元素來過濾集合。
傳回一個集合，只包含 map_set1 和 map_set2 共有的成員。
檢查 map_set 是否包含 值。
傳回一個新的集合。
從一個可列舉物件建立一個集合。
透過轉換函數從一個可列舉物件建立一個集合。
如果 map_set 尚未包含 值，則將 值 插入 map_set 中。
透過排除呼叫 fun 會傳回真值元素的 map_set 元素來傳回一個集合。
傳回 map_set 中的元素數量。
根據指定的函數 fun 將 map_set 分割成兩個 MapSet。
檢查 map_set1 的成員是否都包含在 map_set2 中。
傳回一個集合，其中包含只存在於其中一個集合，但不存在於兩個集合中的元素。
將 map_set 轉換成一個清單。
傳回一個集合，其中包含 map_set1 和 map_set2 的所有成員。
類型
函數
從 map_set 中刪除 值。
傳回一個新的集合，它是 map_set 的拷貝，但沒有 value。
範例
iex> map_set = MapSet.new([1, 2, 3])
iex> MapSet.delete(map_set, 4)
MapSet.new([1, 2, 3])
iex> MapSet.delete(map_set, 2)
MapSet.new([1, 3])傳回一個集合，為 map_set1 減去 map_set2 的成員。
範例
iex> MapSet.difference(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
MapSet.new([1])檢查 map_set1 和 map_set2 是否沒有共同成員。
範例
iex> MapSet.disjoint?(MapSet.new([1, 2]), MapSet.new([3, 4]))
true
iex> MapSet.disjoint?(MapSet.new([1, 2]), MapSet.new([2, 3]))
false檢查兩個集合是否相等。
使用 ===/2 進行元素之間的比較，其中包含 1 的集合與包含 1.0 的集合不相等。
範例
iex> MapSet.equal?(MapSet.new([1, 2]), MapSet.new([2, 1, 1]))
true
iex> MapSet.equal?(MapSet.new([1, 2]), MapSet.new([3, 4]))
false
iex> MapSet.equal?(MapSet.new([1]), MapSet.new([1.0]))
false@spec filter(t(a), (a -> as_boolean(term()))) :: t(a) when a: value()
透過只傳回 map_set 中呼叫 fun 會傳回真值元素來過濾集合。
另請參閱 reject/2，它會捨棄函數傳回真值的所有元素。
效能考量
如果您發現自己在管線中對
MapSet.filter/2和MapSet.reject/2進行多次呼叫，則使用Enum.map/2和Enum.filter/2然後使用MapSet.new/1轉換為集合，可能會更有效率。
範例
iex> MapSet.filter(MapSet.new(1..5), fn x -> x > 3 end)
MapSet.new([4, 5])
iex> MapSet.filter(MapSet.new(["a", :b, "c"]), &is_atom/1)
MapSet.new([:b])傳回一個集合，只包含 map_set1 和 map_set2 共有的成員。
範例
iex> MapSet.intersection(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
MapSet.new([2])
iex> MapSet.intersection(MapSet.new([1, 2]), MapSet.new([3, 4]))
MapSet.new([])檢查 map_set 是否包含 值。
範例
iex> MapSet.member?(MapSet.new([1, 2, 3]), 2)
true
iex> MapSet.member?(MapSet.new([1, 2, 3]), 4)
false@spec new() :: t()
傳回一個新的集合。
範例
iex> MapSet.new()
MapSet.new([])@spec new(Enumerable.t()) :: t()
從一個可列舉物件建立一個集合。
範例
iex> MapSet.new([:b, :a, 3])
MapSet.new([3, :a, :b])
iex> MapSet.new([3, 3, 3, 2, 2, 1])
MapSet.new([1, 2, 3])@spec new(Enumerable.t(), (term() -> val)) :: t(val) when val: value()
透過轉換函數從一個可列舉物件建立一個集合。
範例
iex> MapSet.new([1, 2, 1], fn x -> 2 * x end)
MapSet.new([2, 4])如果 map_set 尚未包含 值，則將 值 插入 map_set 中。
範例
iex> MapSet.put(MapSet.new([1, 2, 3]), 3)
MapSet.new([1, 2, 3])
iex> MapSet.put(MapSet.new([1, 2, 3]), 4)
MapSet.new([1, 2, 3, 4])@spec reject(t(a), (a -> as_boolean(term()))) :: t(a) when a: value()
透過排除呼叫 fun 會傳回真值元素的 map_set 元素來傳回一個集合。
另請參閱 filter/2。
範例
iex> MapSet.reject(MapSet.new(1..5), fn x -> rem(x, 2) != 0 end)
MapSet.new([2, 4])
iex> MapSet.reject(MapSet.new(["a", :b, "c"]), &is_atom/1)
MapSet.new(["a", "c"])@spec size(t()) :: non_neg_integer()
傳回 map_set 中的元素數量。
範例
iex> MapSet.size(MapSet.new([1, 2, 3]))
3根據指定的函數 fun 將 map_set 分割成兩個 MapSet。
fun 會接收 map_set 中的每個元素作為其唯一引數。傳回一個元組，其中第一個 MapSet 包含 map_set 中所有套用 fun 後傳回真值元素，而第二個 MapSet 則包含所有套用 fun 後傳回假值（false 或 nil）的元素。
範例
iex> {while_true, while_false} = MapSet.split_with(MapSet.new([1, 2, 3, 4]), fn v -> rem(v, 2) == 0 end)
iex> while_true
MapSet.new([2, 4])
iex> while_false
MapSet.new([1, 3])
iex> {while_true, while_false} = MapSet.split_with(MapSet.new(), fn {_k, v} -> v > 50 end)
iex> while_true
MapSet.new([])
iex> while_false
MapSet.new([])檢查 map_set1 的成員是否都包含在 map_set2 中。
此函式會檢查 map_set1 是否為 map_set2 的子集。
範例
iex> MapSet.subset?(MapSet.new([1, 2]), MapSet.new([1, 2, 3]))
true
iex> MapSet.subset?(MapSet.new([1, 2, 3]), MapSet.new([1, 2]))
false傳回一個集合，其中包含只存在於其中一個集合，但不存在於兩個集合中的元素。
範例
iex> MapSet.symmetric_difference(MapSet.new([1, 2, 3]), MapSet.new([2, 3, 4]))
MapSet.new([1, 4])將 map_set 轉換成一個清單。
範例
iex> MapSet.to_list(MapSet.new([1, 2, 3]))
[1, 2, 3]傳回一個集合，其中包含 map_set1 和 map_set2 的所有成員。
範例
iex> MapSet.union(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
MapSet.new([1, 2, 3, 4])